Memisahkan Nama Depan dan Nama Belakang

Jika Anda bekerja dengan banyak data yang menggunakan nama orang, suatu saat Anda mungkin ingin memisahkan nama-nama tersebut menjadi dua bagian, yaitu nama dengan dan nama belakang. Dengan menggunkan rumus ini, pekerjaan tersebut sangat mudah dilakukan:

Pada kolom A terdapat nama lengkap, dan pada kolom B anda ingin mengambil nama depannya saja, sedang kolom C anda ingin mengambil nama belakangnya. Maka cukup tuliskan rumus:

=LEFT(A1;FIND(" ";$A$1:$A$16;1)-1)

• LEFT(A1 artinya anda akan mengambil nama dari kolom A1 yang dimulai dari paling kiri.
• FIND(" ";$A$1:$A$16;1)-1 akan mencari karakter spasi " ". Misal pada nama "Aan Arifin" karakter spasi ditemukan pada karakter ke-4, maka nilai yang dihasilkan adalah 4. Rumus -1 artinya angka 4 tadi dikurangi dengan -1 agar menjadi 3, sesuai dengan nama "Aan" yang hanya ada 3 karakter.

=MID(A1;FIND(" ";$A$1:$A$16;1)+1;100)

• =MID(A1; artinya anda akan mengambil nama dari kolom A1 yang dimulai dari tengah.
• FIND(" ";$A$1:$A$16;1)+1, sama seperti rumus FIND di atas, untuk mencari karakter spasi " ", namun kali ini +1 untuk mencari nama belakang. Rumus FIND(" ";$A$1:$A$16;1)+1 akan menghasilkan angka 5, di mana nama "Arifin" dimulai dengan karakter ke-5. Rumus ;100) artinya karakter yang diambil untuk nama belakang diasumsikan 100 karakter.

MEGA FORMULA
sOURCE : http://formula-excel.blogspot.com/2010/06/memisahkan-nama-depan-dan-nama-belakang.html

Memisah Nama Depan, Tengah dan Belakang dengan Fungsi Text

Belajar fungsi-fungsi Excel, rasanya kurang lengkap jika tidak mendalami Text Functions. Beberapa Text Functions yang sudah dikenal luas adalah : LEFT, MID, RIGHT, FIND, UPPER, PROPER, LOWER. Hampir semua pengguna Excel sudah paham luar dalam tentang fungsi-fungsi tersebut. Beberapa fungsi text lain yang akan dibahas saat ini adalah: LEN, SUBSTITUTE, REPT, TRIM 

A. LEN

LEN berfungsi untuk menghitung jumlah karakter dari sebuah text . Contoh : LEN("Saya") menghasilkan 4

B. SUBSTITUTE

SUBSTITUTE berfungsi untuk menganti karakter tertentu dalam text dengan karakter lain. Contoh: =SUBSTITUTE("Saya","a","o",1) menghasilkan : "Soya". Ada 4 elemen dalam fungsi ini, yakni: 

{Text, OldText, NewText, [InstanceNumber]}

Untuk elemen yang keempat atau InstanceNumber jika dikosongkan artinya semua karakter pada Oldtext yang akan diganti.

Jadi rumus =SUBSTITUTE("Saya","a","o") akan menghasilkan "Soyo"

Yang dimaksud InstanceNumber adalah, seperti pada contoh, huruf "a" yang ke berapa yang akan diganti.

C. REPT
REPT berfungsi untuk mengulang suatu karakter sebanyak n kali. Contoh : =REPT("a",2)menghasilkan "aa"


D. TRIM
Berfungsi untuk membuang kelebihan spasi pada sebuah text, di mana spasi di awal text akan dihapus, spasi di tengah text yang lebih dari 1 karakter akan dijadikan 1 karakter dan kelebihan spasi di akahir text akan dihapus. Contoh : 
=TRIM("  Ana    Ahibbuka   ") menghasilkan "Ana Ahibbuka"


Keempat fungsi di atas, tampaknya useless, artinya tidak berguna sama sekali jika hanya dilihat sekilas. Tapi jika digabung dengan  fungs-fungsi yang lain, maka akan tampak sekali kegunaannya.


Berikut saya contohkan penggunaan fungsi-fungsi Text untuk mencari nama depan, nama tengah dan nama belakang.

• Mencari Nama Depan

Mencari nama depan dari sebuah nama bukanlah hal yang sulit. Cara kerjanya adalah dengan mencari posisi spasi, kemudian mengambil karakter sebelah kiri sebanyak posisi spasi dikurangi 1.
Contoh Misal nama lengkap "Ahmad Ahmadi" ada di sel A1, maka rumusnya adalah:

=LEFT(A1,FIND(" ",A1)-1)

• Mencari Nama Belakang

Tinngkat kesulitan mencari nama belakang agak berbeda dengan nama depan. karena nama orang kadang bisa lebih dari dua kata. Misal yang ingin dicari nama belakangnya adalah "Ahmad Nur Putro Bin Salam" ada di sel A1. 
Langkah penyelesaiannya adalah mengambil karakter paling kanan (RIGHT) sejumlah posisi spasi terakhir. Masalah timbul karena jumlah spasi kan bisa jadi tidak sama. Maka kita harus putar otak untuk mencari jumlah spasi terlebih dahulu. Nah, di sinilah fungsi SUBSTITUTE menemukan tempatnya. Dengan SUBSTITUTE kita ganti semua spasi dengan kosong, kemudian Jumlah karakter awal dikurangi dengan jumlah karakter dari kata awal yang telah dibuang spasinya. Lengkapnya begini:

1. Cari Jumlah karakter nama lengkap : =LEN(A1)
2. Buang spasi  : = SUBSTITUTE(A1," ","")
3. Kurangi langkah 1 dengan langkah 2 : =LEN(A1)-LEN(SUBSTITUTE(A1," ","")
4. Berikutnya kita mengganti spasi terakhir dengan karakter "*": SUBSTITUTE(A1," ","*",LEN(A1)-LEN(SUBSTITUTE(A1," ","")))
5. Menemukan spasi terakhir: FInd("*",langkah4) 

Langkah selanjutnya lebih mudah yakni tinggal mengambil karakter paling kanan sejumlah langkah no 5.

=RIGHT(A1,LEN(A1)-FIND("*",SUBSTITUTE(A1," ","*",LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

• Mencari Nama Tengah

Mencari nama tengah adalah pekerjaan paling sulit dalam urusan memecah nama. Kalau logika yang digunakan untuk menyelesaikan kasus ini hanya biasa saja, maka dibutuhkan rumus yang panjang. Orang yang biasa bekerja dengan Excel dituntut untuk berpikir out of the box untuk mencari nama tengah ini dengan mudah. Biasanya kita (termasuk saya) dalam mencoba memecahkan kasus ini berpijak dari rumus mencari nama depan dan belakang di atas. Masalah yang timbul adalah bagaimana menentukan spasi yang akan dijadikan pedoman untuk mengambil nama tengah. Sehingga menurut saya, diperlukan otak yang sedikit miring untuk memacahkan kasus ini secara cerdas. 
Perhatikan rumus yang saya dapat dari milis BelajarExcel berikut:

=TRIM(MID(SUBSTITUTE(A1," ",REPT(" ",99)),99*INT((LEN(A1)-LEN(SUBSTITUTE(A1," ","")))/2),99))

Formula ini sungguh-sungguh cerdik. Formula ini bekerja dengan mengganti semua spasi dengan spasi sebanyak 99, kemudian mengambil karakter di tengah dimulai dari karakter ke (99*(jumlah spasi /2)) sebanyak 99 karakter. Kemudian membuang kelebihan spasi dengan fungsi TRIM. Simple, Cerdik ...!!!!


Well, demikian pembahasan fungsi Text, mudah-mudahan bermanfaat.
File contoh bisa didownload di sini atau di Boxnet pada sidebar.

Source : http://excelheru.blogspot.com/2012/03/memisah-nama-depan-tengah-dan-belakang.html